NTBackup unter Win200x - Bandsicherung per Skript

Die Informationen auf dieser Seite beziehen sich auf:
	NTBackup 2000		NTBackup 2003
	Windows 2000 Server		Windows 2003 Server

Technischer Inhalt:

In Windows 200x kann NTBackup nicht mehr ganz so einfach per Skript verwendet werden wie bei NT4.0.

Die integrierte Medienverwaltung sorgt dafür, daß bereits verwendete Bänder zunächst in den Pool der freien/ verfügbaren Medien verschoben werden müssen.
Soll täglich ein neues Band eingelegt und unabhängig vom Inhalt überschrieben werden, kann das Skript auf diesem FAQ Artikel eingesetzt werden.

So geht's / Verwendung

Zur Verwendung bitte:

• Ein Verzeichnis anlegen, in welchem Skripte etc. gespeichert werden können; ggf. Pfade im Skript anpassen
  Beispiel: c:\admin\backup

• Die benötigten Dateien in dieses Verzeichnis kopieren:

  • Backup Skript
  • "unixdate"-Befehl (für Datumsstring
  • "sleep" Befehl (um n Sekunden zu warten)
  Die Zusatztools gibt es als .exe im Projekt "UnxUtils"; Benutzung laut dortigem Disclaimer auf eigene Gefahr ;-)
  Alternativ kann man "sleep.exe" auch im ResourceKit finden und den Datumsstring ohne zusätzliche unixdate.exe erzeugen (siehe unten).
  unixdate.exe aus dem UnxUtils Paket
  sleep.exe aus dem UnxUtils Paket
  Sourceforge: GNU utilities for Win32 (UnxUtils)

• Eine .bks Datei "bandsicherung.bks" mit NTBackup erzeugen und im angelegten Verzeichnis speichern

• Den Bandlaufwerksnamen/ Gerätenamen ermitteln und im Skript eintragen

• Das Skript ausprobieren und als geplanten Task einrichten

Backup Skript

@echo off
@title Datensicherung
@color 1F

rem ##################################################
rem #   NTBackup-Sicherung auf Band  (v 2005090201)  #
rem #                www.netzprisma.de               #
rem ##################################################

rem Skript, Tools und .bks Dateien in c:\admin\backup
set configdisk=c:
set configdir=%configdisk%\admin\backup
set configbksfile=bandsicherung.bks


rem ######## Sicherung ##########

%configdisk%
cd %configdir%

rem *** Medienverwaltung zurücksetzen ***
rsm.exe refresh /LF"HP C5683A SCSI Sequential Device"
sleep 30

rem Zeitstempel-String erzeugen
for /f "Tokens=1" %%i in ('unixdate +%%Y%%m%%d-%%H%%M') do set dtt=%%i

rem *** Backup starten ***
ntbackup.exe backup "@%configdir%\%configbksfile%" /n "Band %dtt%" /d "Band %dtt%"  ^
             /v:yes /r:no /rs:no /hc:on /m normal /j "Band %dtt%" /l:f /p "4mm DDS" /UM

rem *** Band auswerfen ***
rsm.exe eject /PF"Band %dtt% - 1" /astart

rem *****************************
rem * Ergänzung für Logrotation *
rem *****************************
rem backup_logrotation.bat

rem ************************************
rem * Ergänzung Email-Benachrichtigung *
rem ************************************
rem (hier einfügen)

@echo off
rem Backup-Skript mit NTBACKUP

e:
cd e:\backup

rem Medienverwaltung zurücksetzen
start /wait rsm.exe refresh /LF"HP C5683A SCSI Sequential Device"


rem Bandname generieren
for /f "Tokens=1-4 Delims=/. " %%i in ('date /t') do  set dt=%%i-%%j-%%k-%%l
for /f "Tokens=1" %%i in ('time /t') do set tm=-%%i
set tm=%tm::=-%
set dtt=%dt%%tm%


rem Backup starten
ntbackup.exe backup "@e:\backup\gesamt.bks" /n "Band %dtt%" /d "Band %dtt%"  ^
             /v:yes /r:no /rs:no /hc:on /m normal ^
             /j "Band %dtt%" /l:f /p "4mm DDS" /UM


rem Band auswerfen
rsm.exe eject /PF"Band %dtt% - 1" /astart

C:\
C:\reserve /Exclude
D:\
E:\
E:\installation /Exclude
SystemState

C:\
D:\
D:\exchsrvr\mdbdata  /Exclude
E:\
E:\exchsrvr\mdbdata  /Exclude
SystemState
JET SRV05\Microsoft Information Store\Erste Speichergruppe\

IS \\SRV03
DS \\SRV03

\\SRV02\c$
\\SRV02\d$
\\SRV02\e$
\\SRV02\e$\SUS /Exclude
C:\
D:\
SystemState

Name des Bandlaufwerks

Aus dem Gerätemanager ermitteln oder per Kommandozeile:

rsm view /tlibrary

Beispiel:

	C:\>rsm view /tlibrary
	LIBRARY
	Offlinemedien
	TOSHIBA DVD-ROM SD-M1814
	HP C1537A SCSI Sequential Device
	Der Befehl wurde ausgeführt.

Den Namen in der NTBACKUP-Zeile (im obigen Skript "4mm DDS") entnimmt man am einfachsten dem Ntbackup (Registerkarte "Sichern", links unten), z.B. "LTO Ultrium" oder "4mm DDS":

"Bandname" und Datumsstring optimieren

Möchte man den datumsstring/Bandnamen mit vertretbarem Aufwand unabhängig von der Serverversion und flexibler mit ordentlichem Datum haben, kann man z.B. auf einen anderen Datums-Befehl ausweichen.
Bei Unix kann man die Ausgabe des Datums ordentlich formatieren; mit einem entsprechenden Befehl ("date") aus dem UnxUtils Paket (Benutzung laut dortigem Disclaimer auf eigene Gefahr ;-) ) ist das problemlos möglich. Um Verwechslungen auszuschließen wurde der "date" Befehl im unteren Download umbenannt.

unixdate.exe aus dem UnxUtils Paket

Sourceforge: GNU utilities for Win32 (UnxUtils)

Nun kann der Bandname deutlich einfacher und flexibler generiert werden:

for /f "Tokens=1" %%i in ('unixdate +%%Y%%m%%d-%%H%%M') do set dtt=%%i

ergibt

20050321-0935

NTBackup als Task

Ideal ist die Einrichtung über einen "geplanten Task".
Dieser sollte als spezieller Backup-Benutzer ausgeführt werden, damit Kennwortänderungen des Administrators den Backup-Job nicht beeinflussen. Der Backup-Benutzer sollte Admin-Berechtigungen haben. Wenn man den Job als nicht-Admin ausführt, sind ggf. noch Rechte zu vergeben.

Im geplanten Task sollte die maximale Laufzeit abweichend vom Standardwert (72 Stunden) so eingetragen werden, daß ein ggf. "aufgehängtes" NTBackup automatisch bereinigt wird.

Falls NTBackup dennoch immer wieder mehrmals gestartet im Taskmanager hängen bleibt, kann man vorsorglich einen "kill" Befehl in das Skript einbauen, z.B. mit "pskill" von www.sysinternals.com.

pskill ntbackup
sleep 2
pskill ntbackup
sleep 2
rem (dann folgt das Backup-Skript)

Sonstiges rund um NTBackup

NTBackup und der "errorlevel"

In der Regel setzt NTBackup nach erfolgreichem Ausführen den Errorlevel auf "0" und im Fehlerfall auf einen Wert != 0. Allerdings erhält man auch manchmal im Fehlerfall einen scheinbar sauberen Errorlevel zurück - also kein verlässliches Kriterium, um im Skript auf einen erfolgreichen oder fehlerhaften Backup-Job zu schließen. Ggf. hilft ein Tool. das die Eintragung im Eventlog überprüft oder das gezielt nach bestimmten Fehlermeldungen in der Logdatei sucht.

"start /wait" oder "sleep" Befehle?

start /wait rsm.exe refresh /lf"Bibliotheksname"

Probiert man das auf der Kommandozeile aus, stellt man jedoch fest, daß RSM nicht wie erhofft auf die Beendigung der Bandlaufwerksaktivitäten wartet. Ein "sleep" Befehl ist daher effektiver:

rsm.exe refresh /lf"Bibliotheksname"
sleep 30

Sicherung von Daten übers Netzwerk - Systemstatus nur lokal zu sichern

Datei-Daten können bequem übers Netzwerk gesichert werden. Allerdings kann der Systemstatus NUR lokal gesichert werden. Exchange-DBen sollte funktionieren, wenn auf dem Sicherungs-Server der Exchange System Manager installiert ist.
Abhilfe: Sicherung des Systemstatus jeweils lokal auf Festplatte; diese Sicherungsdateien dann zusammen mit der Dateisicherung vom zentralen Sicherungssystem aus mitsichern.

NTBackup meldet Fehler wenn ESM, aber kein Exchange installiert ist

Q306342 - XADM: "Event ID 8012" Error Message When You Start NTBackup

NTBackup und Sicherung des Systemstatus mit Exchange-Datenbanken

Sichert man den Systemstatus und Exchange-Datenbanken in einem Sicherungsjob und befinden sich die Exchange-DBen auf der Systemplatte, schlägt das Backup fehl.
Abhilfe: Exchange-DBen auf andere Platte schieben und/oder separate NTBackup-Jobs formulieren!
Also z.B. Sicherung des Systemstatus auf Platte und anschließend Backup-Job (ohne Systemstatus in der .bks Datei) auf Band. Falls das nicht klappt, ggf. die Exchange-Datenbank auf Platte sichern und dann die Sicherungsdatei aufs band ziehen.

Im NTBackup-Log findet man dann solche Einträge:

Sicherung begonnen am <Datum> um <Uhrzeit>.
'Sicherung wird bereits erstellt.' wurde von 'Microsoft Informationsspeicher'
bei einem Aufruf von 'HrESEBackupSetup()' zurückgegeben. Zusätzliche Daten '-'
'Funktionen werden in ungültiger Reihenfolge aufgerufen.' wurde von
'Microsoft Informationsdienst' beim Aufruf von 'HrESEBackupClose()'
zurückgegeben. Zusätzliche Daten '-'
Der Vorgang wurde beendet.
[...]
Der Vorgang wurde nicht ordnungsgemäß ausgeführt.
[...]

Q820272 - Der Sicherungsvorgang schlägt fehl, wenn Sie Exchange Server 2003-Datenbanken und Systemstatusinformationen gleichzeitig sichern

Fehlermeldungen des RSM

Unter Umständen erhält man folgende Fehlermeldung:

PMID-Anzeigename kann nicht in GUID konvertiert werden
Unable to convert Pmid Friendly name to GUID

Dies kann sowohl einen falsch geschriebenen Laufwerksgerätenamen als auch ein Problem mit dem Laufwerk bzw. dem Hotfix-Stand des Systems als Ursache haben. Solche Meldungen wurden z.B. beim HP DAT72 Laufwerk gefunden.
Evtl. helfen aktuelle Hotfixes dagegen; man kann auch versuchen statt des Anzeigenamens die GUID des Laufwerks anzugeben.

Weitere Informationen

NP FAQ: NTBackup unter Win200x - Datensicherung auf FestplatteFAQ #203002

NP FAQ: NTBackup - Logdateien und LogrotationFAQ #203003

NP FAQ: NTBackup unter NT 4.0 - Bandsicherung per SkriptFAQ #203004

NP FAQ: NTBackup Win2000 BefehlzeilenparameterFAQ #203021

NP FAQ: NTBackup Win2003 BefehlszeilenparameterFAQ #203023

NP FAQ: RSM Win2000 BefehlzeilenparameterFAQ #203022

Q267574 - Geplante Sicherungen auf allein stehenden Bandlaufwerken schlagen nach Medienwechsel fehl

Q239892 - Planen unbeaufsichtigter Sicherungen mit eigenständiger Bandbibliothek

Q237310 - Manuelles Bearbeiten der Auswahlskriptdateien von "Ntbackup.exe"

Q814583 - HOW TO: Use Command Line Parameters with the Ntbackup Command in Windows Server 2003

Denis Jedig's "Windows 2000 NTBACKUP & RSM Howto"

www.ntbackup.info (Sammlung von KB-Artikeln)