NTBackup mit Windows 2000/2003 – Bandsicherung per Skript

Um Windows 2000 oder 2003 mit NTBackup sichern zu können, muss die integrierte Medienverwaltung berücksichtigt werden. Normalerweise müssen bereits verwendete Bänder zunächst in den Pool der freien/ verfügbaren Medien verschoben werden. Mit dem hier beschriebenen Skript kann ein System mit einem täglich neu eingelegten Band gesichert werden.

Anpassung und Verwendung des Skripts in Ihrer Umgebung

Zur Verwendung bitte:

  • Ein Verzeichnis anlegen, in welchem Skripte etc. gespeichert werden können. Ggf. Pfade im Skript anpassen. Beispiel: c:\admin\backup
  • Die benötigten Dateien in das angelegte Verzeichnis kopieren:
    • Backup Skript
    • unixdate“-Befehl (für Datum-String)
    • sleep” Befehl (um n Sekunden zu warten)

    Die Zusatztools gibt es als .exe im Projekt “UnxUtils”; Benutzung laut dortigem Disclaimer auf eigene Gefahr. Alternativ kann man “sleep.exe” auch im ResourceKit finden und den Datumsstring ohne zusätzliche unixdate.exe erzeugen (siehe unten).
    Hier finden Sie u.a. ein sleep.exe und ein date.exe (haben wir in unixdate.exe umbenannt um Verwechslungen mit dem date Befehl der Windows Shell zu vermeiden):
    Sourceforge: GNU Utilities for Win32 (UnxUtils)

  • Eine .bks Datei “bandsicherung.bks” mit NTBackup erzeugen und im angelegten Verzeichnis speichern
  • Den Bandlaufwerksnamen/ Gerätenamen ermitteln und im Skript eintragen
  • Das Skript ausprobieren und als geplanten Task einrichten

Backup Skript

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
@echo off
@title Datensicherung
@color 1F

rem ##################################################
rem # NTBackup-Sicherung auf Band (v 2005090201) #
rem # www.netzprisma.de #
rem ##################################################

rem Skript, Tools und .bks Dateien in c:\admin\backup
set configdisk=c:
set configdir=%configdisk%\admin\backup
set configbksfile=bandsicherung.bks

rem ######## Sicherung ##########

%configdisk%
cd %configdir%

rem *** Medienverwaltung zurücksetzen ***
rsm.exe refresh /LF"HP C5683A SCSI Sequential Device"
sleep 30

rem Zeitstempel-String erzeugen
for /f "Tokens=1" %%i in ('unixdate +%%Y%%m%%d-%%H%%M') do set dtt=%%i

rem *** Backup starten ***
ntbackup.exe backup "@%configdir%\%configbksfile%" /n "Band %dtt%" /d "Band %dtt%" ^
/v:yes /r:no /rs:no /hc:on /m normal /j "Band %dtt%" /l:f /p "4mm DDS" /UM

rem *** Band auswerfen ***
rsm.exe eject /PF"Band %dtt% - 1" /astart

rem *****************************
rem * Ergänzung für Logrotation *
rem *****************************
rem backup_logrotation.bat

rem ************************************
rem * Ergänzung E-Mail-Benachrichtigung *
rem ************************************
rem (hier einfügen)
Backup Script classic ohne Zusatztools

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
@echo off
rem Backup-Skript mit NTBACKUP

e:
cd e:\backup

rem Medienverwaltung zurücksetzen
start /wait rsm.exe refresh /LF"HP C5683A SCSI Sequential Device"

rem Bandname generieren
for /f "Tokens=1-4 Delims=/. " %%i in ('date /t') do set dt=%%i-%%j-%%k-%%l
for /f "Tokens=1" %%i in ('time /t') do set tm=-%%i
set tm=%tm::=-%
set dtt=%dt%%tm%

rem Backup starten
ntbackup.exe backup "@e:\backup\gesamt.bks" /n "Band %dtt%" /d "Band %dtt%" ^
/v:yes /r:no /rs:no /hc:on /m normal ^
/j "Band %dtt%" /l:f /p "4mm DDS" /UM

rem Band auswerfen
rsm.exe eject /PF"Band %dtt% - 1" /astart

Beispiel .bks Dateien

Falls man die .bks Datei von Hand editiert, erkennt NTBackup evtl. die Auswahl nicht mehr richtig. Dies kann man überprüfen, indem man die .bks Datei mit NTBackup lädt – wird die Auswahl richtig angezeigt, ist die Datei in Ordnung.

Die .bks Dateien müssen bei manuellen Bearbeiten als “Unicode” gespeichert werden.

Ansonsten Auswahl mit NTBackup erstellen und von dort aus als .bks Datei sichern.

Beispiel: Sicherung Dateien und Systemstatus

1
2
3
4
5
6
C:\
C:\reserve /Exclude
D:\
E:\
E:\installation /Exclude
SystemState

Beispiel: Sicherung Exchangeserver 200x
Hinweis: bei Ex2003 auf Win2003 nicht Exchange-Datenbanken und Systemstatus in einem Job so sichern!

1
2
3
4
5
6
7
C:\
D:\
D:\exchsrvr\mdbdata /Exclude
E:\
E:\exchsrvr\mdbdata /Exclude
SystemState
JET SRV05\Microsoft Information Store\Erste Speichergruppe\

Beispiel: Sicherung Exchangeserver 5.5

1
2
IS \\SRV03
DS \\SRV03

Beispiel: Sicherung Laufwerke eines zweiten Servers übers Netz

Am remote gesicherten System sollte zuvor zumindest der Systemstatus auf Festplatte gesichert werden, z.B. mit einem NTBackup-Job, welcher den Systemstatus auf Platte sichert.

Ggf. die “$”-Shares erst in der Netzwerkumgebung über “Netzwerkumgebung hinzufügen” bekannt machen, dann zeigt auch NTBackup diese in der Auswahlliste an.

1
2
3
4
5
6
7
\\SRV02\c$
\\SRV02\d$
\\SRV02\e$
\\SRV02\e$\SUS /Exclude
C:\
D:\
SystemState

Name des Bandlaufwerks

Aus dem Gerätemanager ermitteln oder per Kommandozeile: rsm view /tlibrary

Beispiel:

C:\>rsm view /tlibrary     

LIBRARY     

Offlinemedien     
TOSHIBA DVD-ROM SD-M1814     
HP C1537A SCSI Sequential Device     

Der Befehl wurde ausgeführt.